[Prev][Next][Index][Thread]

No Subject



    [The following text is in the "ISO-8859-1" character set]
    [Your display is set for the "US-ASCII" character set]
    [Some characters may be displayed incorrectly]

Since Malcolm had seen linear decay of the oscillation envelope
 in some measurements on spark-gap type RLC circuits, I had 
been interested in trying to determine what can cause this behavior.
 Of course, a constant R gives exponential decay, so that wasn't
what was going on. Static arc current-voltage curves studied by
Aryton and Nottingham suggest  for an arc (maybe even at
low rf frequencies) that

Vg = A + B/Ig^(n)

Where A , B and n are constants which depend on the geometry,
gap electrode material and the intervening gas. Vg and Ig are
the gap voltage and current respectively.

Thus, the gap resistance:

Rg = A/Ig + B/Ig^(n+1)

An RLC circuit simulation program I wrote, which I include at the
end of this message, shows that indeed a linear decay envelope
can result by assuming the gap has the above Aryton 
behavior!! In fact, only the first term (A/Ig) is necessary to
produce the linear decay. No exponetial decay is seen if
Rg is much bigger than the remaining series resistance of
the circuit.

For you entertainment.

-Ed Harris

--------------------------------- quick basic program
---------------------------------
SCREEN 9
CLS
DEFDBL A-Z


'RLC simulation program with non-linear spark-gap resistance
'function using the Ayrton formula (ref 1)
' Written by Ed Harris 1/10/1997

'Purpose: to see if static arc I-V formulas can account for
'the linear decrement seen in some spark-gap RLC circuits

'Ref 1: Industrial Plasma Engineering, J.R. Roth p372 (1995)

'assume tesla coil approprite components
L = .0001 'Henries  inductor
C = 2E-08 'Farads   capacitor

Rl = .1    'ohm      series resistance of circuit without spark-gap


V = 15000 'volt iniital cap voltage
q = C * V  'initial charge on cap


f0 = 1 / (6.28 * SQR(L * C))  'Hz resonant frequency
t = 1 / f0                    'sec period
Tmax = 30 * t
dt = t / 1000                 'integration interval

'begin the iteration of the differential equations
FOR t = 0 TO Tmax STEP dt

'Here I make up a function for the spark gap resistance based
'The form given by both  Hertha Ayrton (1902) and Nottingham (1923)
'is: Vgap=A+B/Igap^(n) where A and B are constants and n
' is an exponent which depends linearly on the vaporization
'temperature of the electrode material. n is 1.4 for tungsten
'and about 0.7 for Copper oxide. The resistance of the gap is
'then Rg=A/Ig + B/Ig^(n+1)...

'To see the linear decrement of the oscillation I find that
'only the first term is really important. Apparently, this term
'or a similar function which makes the gap resistance "blow up"
'as the current gets small is the curprit in the linear decrement.
'The exact form of the function does not seem important.
' Deviations from the linear decrement are seen if the series
'resistance term Rl is made large (say 2 ohms).


'The iave term gives some delay in the resistance as well
'as keeping the term finite. The number 100 in the Rg expression
'represents the "constant" voltage across the gap, whereas the
'constants 1 and 2.4 are just pulled from thin air. Almost
'anything will work. The second term can also be removed altogether
'and you will still see the linear decrement.

'Finally, note that these equations are non-linear and therefore
'are not completely stable. Some spark-gap parameter chages will
'cause nonsensical results since not all the physics is included
'in these simulations. Hence, the Rg function certainly does not
'work for very small currents.


iave = (ABS(i) + ABS(oldi) + .000001) / 2
Rg = 200 / (iave) + 1 / (iave) ^ 2.4      'ohms
di = -(dt / L) * (i * (Rl + Rg) + q / C)
oldi = i
i = i + di
dq = i * dt
q = q + dq
V = q / C


PSET (t / Tmax * 600, 160 + V / 100)
'next line can be used to plot the gap resistance
'LINE (t / Tmax * 600, 160)-(t / Tmax * 600, 160 + Rg / 100), 5
NEXT t